Macro : Copy Excel Sheets as Workbook

How to copy every sheet in a excel workbook into a new workbook? Visual Basic (VB) Macro code (download a excel workbook) loaded with Excel Macro to Copy Every sheets to (as) New Workbooks with the Sheet Name converted into Workbook with just a click of macro button. You can use below macro code directly into the workbook, which requires sheets to be converted in to different workbook. You can also download a Sample copy of the Copy Every Sheet to New Workbook - Macro Enabled Worksheet.

Copy Every Sheet to New Workbook - Excel Macro

1. Copy below mentioned VB Macro code
2. Open Excel and Press Alt + F11 to open VB Project
3. On left panel, Right click on "This Workbook" under VBA Project
4. Go to Insert > Modules
5. Paste the below copied VB code on the right white panel.
6. Press Cltr + S to save the workbook
7. Click on the Macro Button to copy every sheet to new workbook
8. Enjoy.,

Sub Copy_Every_Sheet_To_New_Workbook()
'Working in 97-2010
Dim FileExtStr As String
Dim FileFormatNum As Long
Dim Sourcewb As Workbook
Dim Destwb As Workbook
Dim sh As Worksheet
Dim DateString As String
Dim FolderName As String

With Application
.ScreenUpdating = False
.EnableEvents = False
.Calculation = xlCalculationManual
End With

'Copy every sheet from the workbook with this macro
Set Sourcewb = ActiveWorkbook

'Create new folder to save the new files in
DateString = Format(Now, "yyyy-mm-dd hh-mm-ss")
FolderName = Sourcewb.Path & "\" & Sourcewb.Name & " " & DateString
MkDir FolderName

'Copy every visible sheet to a new workbook
For Each sh In Sourcewb.Worksheets

'If the sheet is visible then copy it to a new workbook
If sh.Visible = -1 Then
sh.Copy

'Set Destwb to the new workbook
Set Destwb = ActiveWorkbook

'Determine the Excel version and file extension/format
With Destwb
If Val(Application.Version) < 12 Then
'You use Excel 97-2003
FileExtStr = ".xls": FileFormatNum = -4143
Else
'You use Excel 2007-2010
If Sourcewb.Name = .Name Then
MsgBox "Your answer is NO in the security dialog"
GoTo GoToNextSheet
Else
Select Case Sourcewb.FileFormat
Case 51: FileExtStr = ".xlsx": FileFormatNum = 51
Case 52:
If .HasVBProject Then
FileExtStr = ".xlsm": FileFormatNum = 52
Else
FileExtStr = ".xlsx": FileFormatNum = 51
End If
Case 56: FileExtStr = ".xls": FileFormatNum = 56
Case Else: FileExtStr = ".xlsb": FileFormatNum = 50
End Select
End If
End If
End With

'Change all cells in the worksheet to values if you want
If Destwb.Sheets(1).ProtectContents = False Then
With Destwb.Sheets(1).UsedRange
.Cells.Copy
.Cells.PasteSpecial xlPasteValues
.Cells(1).Select
End With
Application.CutCopyMode = False
End If


'Save the new workbook and close it
With Destwb
.SaveAs FolderName _
& "\" & Destwb.Sheets(1).Name & "-" & Sourcewb.Name, _
FileFormat:=FileFormatNum
.Close False
End With

End If
GoToNextSheet:
Next sh

MsgBox "Visit http://routineinfo.com/ for More....Job Done Sir - You can find the files in " & FolderName

With Application
.ScreenUpdating = True
.EnableEvents = True
.Calculation = xlCalculationAutomatic
End With
End Sub

Hope this would have helped you save the time on excel and avoiding the routine work of copying all the sheets to a new workbook manually.... Stay tuned for more excel tips & technique i normally use in my office...

Note : - I am not the author of the Macro..